{一品【三浪启动Z】----创幻论坛一品茶缘编写精品指标，大智慧主图指标}{飞弧通用}
{指标思路：
1、均线流：日均线5、10、30、65、250中线多头排列，而短线处于波浪底部（即二浪回调末端）；
2、偏离率：股价偏离60日线10%以下；股价偏离250日线30%以下；
3、MACD指标连续10天以上处于底部状态；
4、同时符合1+2+3三个条件，说明该股属于中线庄股，锁定目标；
5、当MACD重新走强、股价出现放量上涨之日，就是三浪启动之时——果断买入，等待拉升！}
MA5:MA(CLOSE,5);
MA10:MA(CLOSE,10);
MA30:MA(CLOSE,30);
MA60:=MA(CLOSE,60);
MA65:MA(CLOSE,65);
MA250:MA(CLOSE,250),COLORRED;
突破线:MIN(MA60*1.1,MA250*1.3),POINTDOT,COLOR0066FF;
{差幅:C/MIN(MA60*1.1,MA250*1.3)-1,POINTDOT,COLOR0066FF,LINETHICK1;}
均线流:=(MA5>MA65 AND MA10>MA65 AND MA30>MA65 AND MA5<MA30)*0.3,POINTDOT,COLOR00FF00,LINETHICK3;
PL1:=(CLOSE - MA60) / MA60 < 0.1;
PL2:=(CLOSE - MA250) / MA250 < 0.3;
偏离率:=(PL1 = 1 AND PL2 = 1) * 0.2,STICK,COLORFF00FF,LINETHICK1;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA :=EMA(DIFF,9);
MACD超跌:=COUNT((DIFF<DEA),10)=10;
MACD:=MACD超跌 * "MACD.MACD"(26,12,9)*(-1),STICK,COLORFFFF00,LINETHICK2;
{本行中，大智慧版本选择*(-1)；飞弧版本选择*(1)}
目标:=IF(均线流=0.3 AND MACD超跌 AND 偏离率=0.2 ,0.8,0),COLORWHITE,LINETHICK2;
MBSJ:=BARSLAST(目标 = 0.8);
放量上涨:=V/REF(V,1) >= 1.1 AND C/REF(C,1) >= 1.01;
SZSJ:=BARSLAST(放量上涨 = 1);
MACD金叉:=CROSS(DIFF,DEA);
JCSJ:=BARSLAST(MACD金叉 = 1);
关注:=(MACD金叉 AND REF(MACD,1) < 0)*-0.1,COLOR00FF00;
启动:=(MBSJ <= 20 AND SZSJ <= 1 AND JCSJ <= 1) * 1,COLORYELLOW,LINETHICK2;
突破:=(偏离率 = 0 AND REF(COUNT(偏离率 = 0.2,10) = 10,1) = 1) * -0.1,COLORRED;
{以下设置主图显示方式}
DRAWTEXT(目标=0.8 ,l,'▲'),colorwhite;
DRAWTEXT(关注=-0.1,l,'◆'),color00ff00;
DRAWTEXT(启动,l,'●'),coloryellow;
DRAWTEXT(突破=-0.1,l,'★'),coloryellow;
选股指标：
MA5:=MA(CLOSE,5);
MA10:=MA(CLOSE,10);
MA30:=MA(CLOSE,30);
MA60:=MA(CLOSE,60);
MA65:=MA(CLOSE,65);
MA250:=MA(CLOSE,250);
均线流:=(((((MA5 > MA65) AND (MA10 > MA65)) AND (MA30 > MA65)) AND (MA5 < MA30)) * 0.3);
PL1:=(((CLOSE - MA60) / MA60) < 0.1);
PL2:=(((CLOSE - MA250) / MA250) < 0.3);
偏离率:=(((PL1 = 1) AND (PL2 = 1)) * 0.2);
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA :=EMA(DIFF,9);
MACD超跌:=(COUNT((DIFF < DEA),10) = 10);
MACD:=(MACD超跌 * "MACD.MACD"(26,12,9))*(-1);
目标:=IF(均线流=0.3 ANDMACD AND 偏离率=0.2 ,0.8,0);
MBSJ:=BARSLAST((目标 = 0.8));
放量上涨:=(((VOL / REF(VOL,1)) >= 1.1) AND ((CLOSE / REF(CLOSE,1)) >= 1.01));
SZSJ:=BARSLAST((放量上涨 = 1));
MACD金叉:=CROSS(DIFF,DEA);
JCSJ:=BARSLAST((MACD金叉 = 1));
启动:((((MBSJ <= 20) AND (SZSJ <= 1)) AND (JCSJ <= 1)) * 1); {点击看本软件截图： 58股票 公式网 http://www. 58gu. com 整理} |
